Re: [Question] limit of Plot buffer size

["Mark Verschell" <markv@xxxxxxxxxxxxxxxxxxx>]

As a follow up to Jerry Davison's message:

	I was having a similar problem as Aiko, and since this was a problem I
knew would occur frequently I wrote a .jnl file to do most of the work for me.
I include this below for those that would like to make use of it. The optional
4th argument can be replaced with specific PPLUS commands if desired.

	Mark

******************************Cut Here***************************************

\cancel mode verify
! bplot.jnl - 03/97 by M. Verschell (verschell@coaps.fsu.edu)
!             uses the split_z.jnl file by Joachim Dengg as a template

! Description: allows plotting of regions larger than the 495000 point limit

! usage:  GO bplot variable command [qualifiers] [pplcommands]
! $1 - the variable to be plotted (use quotation marks if it contains commas)
! $2 - the plot command (SHADE, FILL or CONTOUR) (default, "CONTOUR")
! $3 - plot qualifiers (e.g. /LEVELS, /PALETTE) (default, none)
! $4 - optional .jnl file with PPLUS commands (default, no file)

! example:
!   yes? SET DATA eltopo	! Eltopo 5 minute data set (4320x2161 points)
! Note 1: any region must be defined first
!   yes? SET REGION/X=120E:70W/Y=40S:40N ! Still has almost 2,000,000 points
! Note 2: any increase in memory (likely) must be done first
!   yes? set memory/size=4
!   yes? GO bplot eltopo shade "/lev=(0,11000,11000)" pplelt.jnl
! Note 3: this will shade the variable eltopo (above 0m) in 4 strips, calling
!         the GO file pplelt.jnl after the first one to execute various ppl
!         commands to modify the plot
! Note 4: the optional .jnl file should only contain PPLUS commands to modify
!         the entire plot (pen definitions, label commands, etc.), and must not
!         end with a PPLUS SHADE/FILL/CONTOUR.

! Set dafault values and check for argument errors
DEFINE SYMBOL var  $1"<Usage: GO bplot var cmnd [quals] [pplcmnds]"
DEFINE SYMBOL cmnd $2"CONTOUR"
DEFINE SYMBOL qual $3"SET_UP"

! Determine extent of plot region
LET/QUIET ilo=`($var),RETURN=ISTART`
LET/QUIET xlo=X[g=($var),I=`ilo`]
LET/QUIET ihi=`($var),RETURN=IEND`
LET/QUIET xhi=X[g=($var),I=`ihi`]
LET/QUIET jlo=`($var),RETURN=JSTART`
LET/QUIET jhi=`($var),RETURN=JEND`
LET/QUIET itot=ihi-ilo+1
LET/QUIET jtot=jhi-jlo+1
LET/QUIET idel=INT(495000/jtot)

! Plot first region strip
(($cmnd)/($qual)/XLIMITS=`xlo`:`xhi`/SET_UP ($var)[I=`ilo`:`ilo+idel-1`])
IF $4"0|*>1" THEN GO $4"none"
PPL ($cmnd)

! Plot remaining strips (this is 1 long line not 2 lines)
REPEAT/I=`ilo+idel`:`ihi`:`idel` (($cmnd)/($qual)/OVER/NOLABELS
($var)[I=`i`:`i+idel-1`])

! Clean up
CANCEL SYMBOL var
CANCEL SYMBOL cmnd
CANCEL SYMBOL qual
SET MODE/LAST VERIFY

-- 
-------------------------------------------------------------------------------

	      Dr. Mark Verschell (verschell@coaps.fsu.edu)
	      Center for Ocean and Atmospheric Prediction Studies
	      Florida State University
              2035 E. Paul Dirac Drive
              R.M. Johnson Bldg. - Suite 200
	      Tallahassee, FL  32306-3041
	      (904) 644-6935              (904) 644-4841 (fax)