Re: [ferret_users] Re: stippling on the polar stereographic plots

[Pratik Kad <pratikkad17@xxxxxxxxx>]

Dear Saurabh,

I am also struggling sometimes with ferret map projection. Thanks for highlighting the map projection query (as well as this will be helpful for others). 

1. Regarding stippling, maybe following commands can be useful. 

!-/-/-/-/-/-/-/-/-/-/-/-/-/-/-/-/-/-/-/-/-/-/-/-/-/-/-/

let mmmm = if mask lt 0 then 1

let xpts = x[gx=mmmm]+0*y[gy=mmmm]

let ypts = y[gy=mmmm]+0*y[gx=mmmm]

plot/vs/ov/SYMBOL=dot/nolab/nokey/size=0.15/opacity=90 mmmm*xpts*mp_mask, mmmm*ypts*mp_mask, x_page, y_page

!-/-/-/-/-/-/-/-/-/-/-/-/-/-/-/-/-/-/-/-/-/-/-/-/-/-/-/

**However, here we can't control stippling density. 

2. Regarding viewports, the following script might be helpful. 

!-/-/-/-/-/-/-/-/-/-/-/-/-/-/-/-/-/-/-/-/-/-/-/-/-/-/-/

set mem/size=1000

set window/quality=high

use coads_climatology

sh d

define view/axes/xlimit=0.10:0.45/y=0.20:0.80 view_1

define view/axes/xlimit=0.55:0.90/y=0.20:0.80 view_2

set region/x=0:360/y=90S:30S

let mean =WSPD[l=@ave]

set view view_1

go mp_stereographic_south 180 0; GO mp_grid mean ; SET GRID mean ; palette cmocean_dense

fill/NOAXIS/lev=(2,20,2)(inf)/pal=cmocean_dense/nolab/set mean*mp_mask, x_page, y_page

ppl fill

go mp_fland 20

go mp_land

label/nouser `($ppl$xlen)*0.50`,`($ppl$ylen)*-0.1`,0,0,0.32 "@c013 @SR Wind speed"

let mean =SST[l=@ave]

set view view_2

go mp_stereographic_south 180 0; GO mp_grid mean ; SET GRID mean

fill/NOAXIS/lev=(-inf)(-25,25,2.5)(inf)/palette=blue_orange/nolab/set mean*mp_mask, x_page, y_page

ppl fill

go mp_fland 20

go mp_land

!GO mp_graticule

label/nouser `($ppl$xlen)*0.50`,`($ppl$ylen)*-0.1`,0,0,0.32 "@c013 @SR SST"

!-/-/-/-/-/-/-/-/-/-/-/-/-/-/-/-/-/-/-/-/-/-/-/-/-/-/-/

Best regards

pratik

On Mon, Apr 24, 2023 at 4:54 PM saurabh rathore <rohitsrb2020@xxxxxxxxx> wrote:

Dear Ferreters

Apart from the above problem the " go multi_view" also not working with the multiple subplots of stereographic projection. On plotting viewport a12, the previous viewport a11 disappeared from the plot. 

Any help or suggestion will be appreciated. 

Cheers, Saurabh

On Mon, Apr 24, 2023 at 2:55 PM saurabh rathore <rohitsrb2020@xxxxxxxxx> wrote:

Dear Ferreters

G'day

I have a problem with not plotting the stippling on the polar stereographic plot. I tried to search in ferret FAQs but no such problem is mentioned. 

Here are the lines of codes that I am trying to run. 

use "hist-ensemble.nc"
use etopo60

use etopo60
let ro=rose[d=2,gx=slope[d=1,m=1],gy=slope[d=1,m=1]]
let ocean=if ro lt 0 then 1

let stdd = slope[m=@std,d=1]*30*12*1000
let mask = (if abs(slope[m=@ave,d=1]*30*12*1000) ge (2*(stdd/28^0.5)) then 1)*ocean

let nx = `mask,return=isize`
let ny = `mask,return=jsize`
let lon = x[gx=mask,i=1:`nx`:6] + 0*y[gy=mask,j=1:`ny`:6]
let lat = 0*x[gx=mask,i=1:`nx`:6] + y[gy=mask,j=1:`ny`:6]
let p95 = if mask[i=1:`nx`:6,j=1:`ny`:6] eq mask[i=1:`nx`:6,j=1:`ny`:6] then 1 else 0

set grid slope[d=1] ; palette cmocean_balance

go mp_stereographic_south 180 0
set region/y=89.5S:30S/x=20:380.5
go mp_aspect
set viewport a11
fill/lev=(-inf)(-2.5,2.5,0.5)(inf)/nokey/nolab/NOAXIS slope[m=@ave,d=1]*mp_mask, x_page, y_page
go mp_fland 20
go mp_land

plot/nolab/nokey/vs/ov/sym=dot p95*lon*mp_mask, p95*lat*mp_mask, x_page, y_page

ERROR MESSAGE

**ERROR: dimensions improperly specified: unequal line lengths:
          First _expression_ has 1800 points.
          _expression_ 3 has 21660 points:
          "plot/nolab/nokey/vs/ov/sym=dot/size=0.15/opacity=90 p95*lon*mp_mask, p95*lat*mp_mask, x_page, y_page"
plot/nolab/nokey/vs/ov/sym=dot/size=0.15/opacity=90 p95*lon*mp_mask, p95*lat*mp_mask, x_page, y_page
Command file, command group, or REPEAT execution aborted
Executed by script: *** GO tsl-south-stereo.jnl ***