Re: Ambiguous coordinates on X axis

[Jaison Kurian <jaison@xxxxxxxxxxxxxxxxxx>]

Hi Hiroyuki Tomita,
                   If the variables involved in a multivariable expression
are having same size but different co-ordinate values (along any of the
axis:X, Y, Z & T) or the co-ordinate axis have different names, then Ferret
will issue a warning message as :

      " *** NOTE: Ambiguous coordinates on ?? axis: EXPRESSION "

 As you mensioned, your vaiables are identical exept in axes names (first
dataset have axes "LON" & "LAT" but second dataset have "LONGITUDE" and 
"LATITUDE"). Eventhouh the co-ordinate values for the X and Y axes are same
for both the datasets, since the axes names are different, in your case 
Ferret issues the above warning message. This message is issued just for 
our information and nothing wrong with it. Please note that for a fill plot,
even if both the underlying axes for the variables involved are different,
the message will be issued only for the first co-ordinate axis encountered
from the sequence X, Y, Z & T.

 If you want to get rid of this message, then define "diff" as
 
   yes? define grid/like=slp[d=1] gcommon
   yes? let diff=slp[d=1] - slp2[d=2,g=gcommon]

Few earlier mails in the archive regarding this warning message are :

http://ferret.pmel.noaa.gov/Ferret/Mail_Archives/fu_2003/msg00096.html
http://ferret.pmel.noaa.gov/Ferret/Mail_Archives/fu_2004/msg00216.html

And in the user manual you can look at

Ch3 Sec2.2.  Multi-dimensional expressions 


           Please have a look at the example given below.

Hope This Helps

With Regards 

Jaison 

!-----------example.jnl---------------------------------------------------
\ cancel mode verify

! consider two variables defined over two X-axes with the same co-ordinate
!    points/values but different names.

     define axis/x=1:50:1/units=longitudes lon
     define axis/x=1:50:1/units=longitudes longitude
     
     let v1   = x[gx=lon]
     let v2   = x[gx=longitude]

     let sum  = v1 + v2
     plot sum           ! in this case the warning message will appear
 
     pause
 
     let v3   = x[gx=lon]

     let sum1 = v1 + v3
     plot/ov sum1       ! in this case no warning message will appear

     pause 

     define grid/like=v1 gcommon

     let sum2 = v1 + v2[g=gcommon]
     plot/ov sum2      ! in this case no warning message will appear

!----------end of example.jnl-----------------------------------------


On Sun, 17 Apr 2005, Hiroyuki Tomita wrote:

> Ferreters,
> 
> I have a question about a let command.
> I am getting an NOTE as follows.
> Why does the NOTE occur?
> 
> yes? let diff=slp[d=1] - slp2[d=2]
> yes? fill diff[l=1]
>   *** NOTE: Ambiguous coordinates on X axis: SLP[D=1] - SLP2[D=2]
> yes?
> 
> But both my variables are identical in terms of grid and axes as 
> follows.
> 
> yes? sho grid slp[d=1] slp2[d=2]
>      GRID GOV1
>   name       axis              # pts   start                end
>   LON       LONGITUDE          144mr   0E                   2.5W
>   LAT       LATITUDE            73 r   90S                  90N
>   normal    Z
>   TIME      TIME               540 i   01-SEP-1957 00:00    01-AUG-2002 
> 00:00
>      GRID GFM1
>   name       axis              # pts   start                end
>   LONGITUDE LONGITUDE          144mr   0E                   2.5W
>   LATITUDE  LATITUDE            73 r   90S                  90N
>   normal    Z
>   TIME      TIME               540 i   01-SEP-1957 00:00    01-AUG-2002 
> 00:00
> yes?
> 
> 
> Thank you.
> 
> Hiroyuki Tomita
> 

-- 
___________________________________________________

    Jaison Kurian                           
    Centre for Atmospheric and Oceanic Sciences
    Indian Institute of Science
    B A N G A L O R E   560 012
    Ph: +91-80-3942505
        +91-80-3600450
    Fax:+91-80-3600865
___________________________________________________