Re: Heat content in the mixed layer

[Mick Spillane <spillane@xxxxxxxxxxxxx>]

Hi Satheesh,
	There are probably several ways to do this but here is one that
makes sense to me.  Here is a demo based on the levitus climatology for
part of the north pacific

set mode interp
use levitus_climatology
region/x=180:220/y=45:60

let pres=z[g=temp]  ! use depth in meters as pressure in decibars
                    ! there is a more accurate way to do this i'm sure
let sig=rho_un(salt,temp,pres)-1000
let delta=sig-(sig[k=1]+0.2)
let mld=delta[z=@loc:0]         ! a definition of mixed layer depth

! look at what MLD looks like in the region of interest
fill mld

! it appears to have a maximum of about 40

! now define the "heat variable" however you want to. there is material in
! the archives about how Cp can be defined as a function of temp,salt,pres
! but for simplicity here I'll omit that and simply force Cp to be 1.0

let cp = temp/temp
let heat = sig*cp*temp

! now lets linearly interpolate the heat variable to a finer vertical
! scale spanning the range of MLD expected - say with 1 meter resolution
! as in the new depth variable pres1m
def axis/z=0:50:1 zax1m ; def grid/like=temp/z=zax1m grd1m
let heat1m=heat[g=grd1m] ; let pres1m=z[g=grd1m]

! then mask out heat values below the mixed layer depth
let heatmask = if(pres1m le mld)then heat1m

! and integrate heatmask over all depths - only those above the MLD
! will contribute
let heatcontent=heatmask[z=@din]

! lets see what it looks like - a check at one location ...
plot/x=167.5W/y=50.5N/z=0:100 heat,heat1m,heatmask
list/x=167.5W/y=50.5N mld
plot/o/vs/nolab/line=4 {105,165},{26.88,26.88}

! ... then a contour over the region
fill heatcontent

Hope this helps.  There are probably ways to improve it as I didn't put
much thought into how the "heat" variable should be defined.  There are
probably slicker ways too, but with this one you can easily picture what
it is you are calculating.

Good luck,
Mick

|____Mick.Spillane@noaa.gov____|
|__Room 2070 Bldg#3 NOAA/PMEL__|
|____Phone_:_(206)526-6780_____|