Re: plot/vs y-axis, var (fwd)

[Mick.Spillane@xxxxxxxx]

Hi Michael,
	You have made the right first step in your labelling problem,
in using plot/vs/j=...

To summarize the issue:

 1) You need to make the latitude axis be horizontal rather than its
    default vertical. (If issues 2,3 below were not involved I think
    plot/transpose would do the trick)
 2) You want to label (in latitude notation) the actual grid values
    rather than the "nice" values that the ferret/ppl axis generator
    would create.
 3) The grid values themselves have differing numbers of digits after
    the decimal point.
 4) Some of the latitudes are negative (southern hemisphere)

Here is a demo that provides a solution, there may be others

def axis/x=160e:150w:1/units=longitude xax
def axis/y=9.75s:50.25n/npoints=14/units=latitude yax
def grid/x=xax/y=yax grd
let/title="My Variable" v=x[g=grd]+y[g=grd]
list/form=(f8.4) y[g=grd] ! to see how odd the y-values are.)

! form the basic plot without latitude axis values or title
plot/vs/set/line=1/title=" " j[g=grd],v[x=@ave]
ppl axlabp,0,-1 ;ppl yfor,(i3) ; ppl plot
! if you allowed a title here it would be poorly placed because
! of the (initially) missing x-axis values

! make a variable to represent latitude axis values to 2 decimal places)
let yval=int(100*y[g=grd])/100

! apply the southern axis labels ...
repeat/j=1:3 (label `j` 172 0 0 0.08 @sr`(-1)*yval`#S)

! ... then the northern hemisphere ones
repeat/j=4:14 (label `j` 172 0 0 0.08 @sr`yval`#N)

! add the plot title as a label
label/nouser 4 -0.6 0 0 0.2 @crZonal Average

Good luck,
Mick

|____Mick.Spillane@noaa.gov____|
|__Room 2070 Bldg#3 NOAA/PMEL__|
|____Phone_:_(206)526-6780_____|